Rename 12 to 14 and 11 to 13

part13/.gitignore

@@ -0,0 +1 @@
+!Auth.elm

part13/Main.elm

@@ -0,0 +1,126 @@
+module Main exposing (..)
+
+import Page.Home
+import Page.Repository
+import Navigation
+import Page exposing (Page(..))
+import Tuple2
+import Html exposing (Html, div, h1, header, text, span)
+import Html.Attributes exposing (class)
+import Html.App as Html
+
+
+type Model
+    = Home Page.Home.Model
+    | Repository Page.Repository.Model
+    | NotFound
+
+
+type Msg
+    = HomeMsg Page.Home.Msg
+    | RepositoryMsg Page.Repository.Msg
+
+
+main : Program Never
+main =
+    Navigation.program (Navigation.makeParser Page.parser)
+        { init = init
+        , subscriptions = subscriptions
+        , view = view
+        , update = update
+        , urlUpdate = urlUpdate
+        }
+
+
+subscriptions : Model -> Sub Msg
+subscriptions model =
+    case model of
+        Home pageModel ->
+            Page.Home.subscriptions pageModel
+                |> Sub.map HomeMsg
+
+        Repository pageModel ->
+            -- Repository has no subscriptions, so there's nothing to translate!
+            Sub.none
+
+        NotFound ->
+            -- NotFound has no subscriptions, so there's nothing to translate!
+            Sub.none
+
+
+init : Result String Page -> ( Model, Cmd Msg )
+init result =
+    case result of
+        Ok (Page.Home) ->
+            Page.Home.init
+                |> Tuple2.mapEach Home (Cmd.map HomeMsg)
+
+        Ok (Page.Repository repoOwner repoName) ->
+            Page.Repository.init repoOwner repoName
+                |> Tuple2.mapEach Repository (Cmd.map RepositoryMsg)
+
+        Ok (Page.NotFound) ->
+            ( NotFound, Cmd.none )
+
+        Err err ->
+            ( NotFound, Cmd.none )
+
+
+view : Model -> Html Msg
+view model =
+    withHeader <|
+        case model of
+            Home pageModel ->
+                Page.Home.view pageModel
+                    |> Html.map HomeMsg
+
+            Repository pageModel ->
+                Page.Repository.view pageModel
+                    |> Html.map RepositoryMsg
+
+            NotFound ->
+                h1 [] [ text "Page Not Found" ]
+
+
+withHeader : Html msg -> Html msg
+withHeader innerContent =
+    div [ class "content" ]
+        [ header []
+            [ h1 [] [ text "ElmHub" ]
+            , span [ class "tagline" ] [ text "Like GitHub, but for Elm things." ]
+            ]
+        , innerContent
+        ]
+
+
+update : Msg -> Model -> ( Model, Cmd Msg )
+update msg model =
+    case ( msg, model ) of
+        ( HomeMsg pageMsg, Home pageModel ) ->
+            Page.Home.update pageMsg pageModel
+                |> Tuple2.mapEach Home (Cmd.map HomeMsg)
+
+        ( RepositoryMsg pageMsg, Repository pageModel ) ->
+            Page.Repository.update pageMsg pageModel
+                |> Tuple2.mapEach Repository (Cmd.map RepositoryMsg)
+
+        _ ->
+            ( model, Cmd.none )
+
+
+urlUpdate : Result String Page -> Model -> ( Model, Cmd Msg )
+urlUpdate result model =
+    case result of
+        Ok (Page.Home) ->
+            Page.Home.init
+                |> Tuple2.mapEach Home (Cmd.map HomeMsg)
+
+        Ok (Page.Repository repoOwner repoName) ->
+            Page.Repository.init repoOwner repoName
+                |> Tuple2.mapEach Repository (Cmd.map RepositoryMsg)
+
+        Ok (Page.NotFound) ->
+            ( NotFound, Cmd.none )
+
+        Err err ->
+            ( NotFound, Cmd.none )

part13/Page.elm

@@ -0,0 +1,26 @@
+module Page exposing (..)
+
+import Navigation
+import UrlParser exposing (Parser, (</>), format, int, s, string)
+import String
+
+
+type Page
+    = Home
+    | Repository String String
+    | NotFound
+
+
+pageParser : Parser (Page -> a) a
+pageParser =
+    UrlParser.oneOf
+        [ format Home (s "")
+        , format Repository (s "repositories" </> string </> string)
+        ]
+
+
+parser : Navigation.Location -> Result String Page
+parser location =
+    location.pathname
+        |> String.dropLeft 1
+        |> UrlParser.parse identity pageParser

part13/Page/Home.elm

@@ -0,0 +1,212 @@
+port module Page.Home exposing (..)
+
+import Html exposing (..)
+import Html.Attributes exposing (class, target, href, property, defaultValue)
+import Html.Events exposing (..)
+import Auth
+import Json.Decode exposing (Decoder)
+import Json.Decode.Pipeline exposing (decode, required)
+import Navigation
+import Table
+
+
+type alias SearchResult =
+    { id : Int
+    , name : String
+    , stars : Int
+    }
+
+
+searchResultDecoder : Decoder SearchResult
+searchResultDecoder =
+    decode SearchResult
+        |> required "id" Json.Decode.int
+        |> required "full_name" Json.Decode.string
+        |> required "stargazers_count" Json.Decode.int
+
+
+getQueryString : String -> String
+getQueryString query =
+    -- See https://developer.github.com/v3/search/#example for how to customize!
+    "access_token="
+        ++ Auth.token
+        ++ "&q="
+        ++ query
+        ++ "+language:elm&sort=stars&order=desc"
+
+
+responseDecoder : Decoder (List SearchResult)
+responseDecoder =
+    Json.Decode.at [ "items" ] (Json.Decode.list searchResultDecoder)
+
+
+type alias Model =
+    -- TODO add tableState : Table.State to the Model
+    { query : String
+    , results : List SearchResult
+    , errorMessage : Maybe String
+    }
+
+
+type Msg
+    = Search
+    | Visit String
+    | SetQuery String
+    | DeleteById Int
+    | HandleSearchResponse (List SearchResult)
+    | HandleSearchError (Maybe String)
+      -- TODO add a new constructor: SetTableState Table.State
+    | DoNothing
+
+
+initialQuery : String
+initialQuery =
+    "tutorial"
+
+
+init : ( Model, Cmd Msg )
+init =
+    -- TODO initialize the Model's tableState to (Table.initialSort "Stars")
+    ( { query = initialQuery
+      , results = []
+      , errorMessage = Nothing
+      }
+    , githubSearch (getQueryString initialQuery)
+    )
+
+
+view : Model -> Html Msg
+view model =
+    let
+        currentTableState : Table.State
+        currentTableState =
+            -- TODO have this use the actual current table state
+            Table.initialSort "Stars"
+    in
+        div [ class "home-container" ]
+            [ input [ class "search-query", onInput SetQuery, defaultValue model.query ] []
+            , button [ class "search-button", onClick Search ] [ text "Search" ]
+            , viewErrorMessage model.errorMessage
+              -- TODO have this use model.results instead of []
+            , Table.view tableConfig currentTableState []
+            ]
+
+
+tableConfig : Table.Config SearchResult Msg
+tableConfig =
+    Table.config
+        { toId = .id >> toString
+        , toMsg =
+            -- TODO have the table use SetTableState for its toMsg
+            (\tableState -> DoNothing)
+        , columns = [ starsColumn, nameColumn ]
+        }
+
+
+starsColumn : Table.Column SearchResult Msg
+starsColumn =
+    Table.veryCustomColumn
+        { name = "Stars"
+        , viewData = viewStars
+        , sorter = Table.increasingOrDecreasingBy (negate << .stars)
+        }
+
+
+nameColumn : Table.Column SearchResult Msg
+nameColumn =
+    Table.veryCustomColumn
+        { name = "Name"
+        , viewData = viewSearchResult
+        , sorter = Table.increasingOrDecreasingBy .name
+        }
+
+
+viewErrorMessage : Maybe String -> Html a
+viewErrorMessage errorMessage =
+    case errorMessage of
+        Just message ->
+            div [ class "error" ] [ text message ]
+
+        Nothing ->
+            text ""
+
+
+viewStars : SearchResult -> Table.HtmlDetails Msg
+viewStars result =
+    Table.HtmlDetails []
+        [ span [ class "star-count" ] [ text (toString result.stars) ] ]
+
+
+viewSearchResult : SearchResult -> Table.HtmlDetails Msg
+viewSearchResult result =
+    Table.HtmlDetails []
+        [ a [ onClick (Visit ("/repositories/" ++ result.name)) ] [ text result.name ]
+        , button [ class "hide-result", onClick (DeleteById result.id) ]
+            [ text "X" ]
+        ]
+
+
+update : Msg -> Model -> ( Model, Cmd Msg )
+update msg model =
+    case msg of
+        Visit url ->
+            ( model, Navigation.newUrl url )
+
+        Search ->
+            ( model, githubSearch (getQueryString model.query) )
+
+        SetQuery query ->
+            ( { model | query = query }, Cmd.none )
+
+        HandleSearchResponse results ->
+            ( { model | results = results }, Cmd.none )
+
+        HandleSearchError error ->
+            ( { model | errorMessage = error }, Cmd.none )
+
+        DeleteById idToHide ->
+            let
+                newResults =
+                    model.results
+                        |> List.filter (\{ id } -> id /= idToHide)
+
+                newModel =
+                    { model | results = newResults }
+            in
+                ( newModel, Cmd.none )
+
+        -- TODO add a new branch for SetTableState
+        -- which records the new tableState in the Model.
+        DoNothing ->
+            ( model, Cmd.none )
+
+
+decodeGithubResponse : Json.Decode.Value -> Msg
+decodeGithubResponse value =
+    case Json.Decode.decodeValue responseDecoder value of
+        Ok results ->
+            HandleSearchResponse results
+
+        Err err ->
+            HandleSearchError (Just err)
+
+
+decodeResponse : Json.Decode.Value -> Msg
+decodeResponse json =
+    case Json.Decode.decodeValue responseDecoder json of
+        Err err ->
+            HandleSearchError (Just err)
+
+        Ok results ->
+            HandleSearchResponse results
+
+
+subscriptions : Model -> Sub Msg
+subscriptions _ =
+    githubResponse decodeResponse
+
+
+port githubSearch : String -> Cmd msg
+
+
+port githubResponse : (Json.Decode.Value -> msg) -> Sub msg

part13/Page/Repository.elm

@@ -0,0 +1,136 @@
+module Page.Repository exposing (..)
+
+import Html exposing (..)
+import Html.Attributes exposing (class, target, href, property, defaultValue, src)
+import Auth
+import Http
+import Task
+import Json.Decode exposing (Decoder, int, string, list)
+import Json.Decode.Pipeline exposing (decode, required)
+
+
+type alias Model =
+    { repoOwner : String
+    , repoName : String
+    , repository : Maybe Repository
+    }
+
+
+type alias Repository =
+    { id : Int
+    , issues : Int
+    , forks : Int
+    , watchers : Int
+    , owner : User
+    , description : String
+    }
+
+
+type alias User =
+    { id : Int
+    , username : String
+    , avatarUrl : String
+    , profileUrl : String
+    }
+
+
+userDecoder : Decoder User
+userDecoder =
+    decode User
+        |> required "id" int
+        |> required "login" string
+        |> required "avatar_url" string
+        |> required "url" string
+
+
+repoDecoder : Decoder Repository
+repoDecoder =
+    decode Repository
+        |> required "id" int
+        |> required "open_issues_count" int
+        |> required "forks" int
+        |> required "watchers" int
+        |> required "owner" userDecoder
+        |> required "description" string
+
+
+init : String -> String -> ( Model, Cmd Msg )
+init repoOwner repoName =
+    ( { repoOwner = repoOwner
+      , repoName = repoName
+      , repository = Nothing
+      }
+    , getRepoInfo repoOwner repoName
+    )
+
+
+view : Model -> Html Msg
+view model =
+    let
+        ownerUrl =
+            "https://github.com/" ++ model.repoOwner
+
+        repoUrl =
+            ownerUrl ++ "/" ++ model.repoName
+
+        details =
+            model.repository
+                |> Maybe.map viewDetails
+                |> Maybe.withDefault (text "")
+    in
+        div []
+            [ h2 []
+                [ a [ href repoUrl ] [ text model.repoName ] ]
+            , details
+            ]
+
+
+viewDetails : Repository -> Html Msg
+viewDetails repo =
+    div []
+        [ p [ class "repo-description" ] [ text repo.description ]
+        , h3 []
+            [ a [ href repo.owner.profileUrl ]
+                [ img [ class "profile-photo", src repo.owner.avatarUrl ] []
+                , text repo.owner.username
+                ]
+            ]
+        , table []
+            [ tbody []
+                [ tr [] [ th [] [ text "issues" ], td [] [ text (toString repo.issues) ] ]
+                , tr [] [ th [] [ text "forks" ], td [] [ text (toString repo.forks) ] ]
+                , tr [] [ th [] [ text "watchers" ], td [] [ text (toString repo.watchers) ] ]
+                ]
+            ]
+        ]
+
+
+type Msg
+    = HandleRepoError Http.Error
+    | HandleRepoResponse Repository
+
+
+getRepoInfo : String -> String -> Cmd Msg
+getRepoInfo repoOwner repoName =
+    let
+        url =
+            "https://api.github.com/repos/"
+                ++ repoOwner
+                ++ "/"
+                ++ repoName
+                ++ "?access_token="
+                ++ Auth.token
+                |> Debug.log "getRepoInfo"
+    in
+        Http.get repoDecoder url
+            |> Task.perform HandleRepoError HandleRepoResponse
+
+
+update : Msg -> Model -> ( Model, Cmd Msg )
+update msg model =
+    case msg of
+        HandleRepoError err ->
+            ( model, Cmd.none )
+
+        HandleRepoResponse repository ->
+            ( { model | repository = Just repository }, Cmd.none )

part13/README.md

@@ -0,0 +1,22 @@
+Part 11
+=======
+
+## Installation
+
+```bash
+elm-package install
+```
+
+(Answer `y` when prompted.)
+
+
+## Building
+
+```bash
+elm-live Main.elm --open --pushstate --output=elm.js
+```
+
+## References
+
+* [Scaling the Elm Architecture](http://guide.elm-lang.org/reuse/)
+* [Sortable Table documentation](http://package.elm-lang.org/packages/evancz/elm-sortable-table/latest)

part13/elm-package.json

@@ -0,0 +1,22 @@
+{
+    "version": "1.0.0",
+    "summary": "Like GitHub, but for Elm stuff.",
+    "repository": "https://github.com/rtfeldman/elm-workshop.git",
+    "license": "BSD-3-Clause",
+    "source-directories": [
+        ".",
+        ".."
+    ],
+    "exposed-modules": [],
+    "dependencies": {
+        "Fresheyeball/elm-tuple-extra": "2.1.0 <= v < 3.0.0",
+        "NoRedInk/elm-decode-pipeline": "1.1.2 <= v < 2.0.0",
+        "elm-lang/core": "4.0.1 <= v < 5.0.0",
+        "elm-lang/html": "1.0.0 <= v < 2.0.0",
+        "elm-lang/navigation": "1.0.0 <= v < 2.0.0",
+        "evancz/elm-http": "3.0.1 <= v < 4.0.0",
+        "evancz/elm-sortable-table": "1.0.0 <= v < 2.0.0",
+        "evancz/url-parser": "1.0.0 <= v < 2.0.0"
+    },
+    "elm-version": "0.17.0 <= v < 0.18.0"
+}

part13/index.html

@@ -0,0 +1,32 @@
+<!DOCTYPE HTML>
+<html>
+
+<head>
+  <meta charset="UTF-8">
+  <title>ElmHub</title>
+  <script type="text/javascript" src="/github.js"></script>
+  <script type="text/javascript" src="/elm.js"></script>
+  <link rel="stylesheet" href="/style.css">
+  <link rel="icon" type="image/png" href="/elm-hub.png">
+</head>
+
+<body>
+  <div id="elm-landing-pad"></div>
+</body>
+
+<script type="text/javascript">
+  // documentation: https://github.com/michael/github
+  var github = new Github();
+
+  var app = Elm.Main.embed(document.getElementById("elm-landing-pad"));
+
+  function searchGithub(query) {
+    github.getSearch(query).repositories({}, function (err, repositories) {
+      app.ports.githubResponse.send(repositories);
+    });
+  }
+
+  app.ports.githubSearch.subscribe(searchGithub);
+</script>
+
+</html>

part13/style.css

@@ -0,0 +1,131 @@
+
+.content {
+  width: 960px;
+  margin: 0 auto;
+  padding: 30px;
+  font-family: Helvetica, Arial, serif;
+}
+
+header {
+  position: relative;
+  padding: 6px 12px;
+  height: 36px;
+  background-color: rgb(96, 181, 204);
+}
+
+h1 {
+  color: white;
+  font-weight: normal;
+  margin: 0;
+}
+
+.tagline {
+  color: #eee;
+  position: absolute;
+  right: 16px;
+  top: 12px;
+  font-size: 24px;
+  font-style: italic;
+}
+
+.results {
+  list-style-image: url('http://img-cache.cdn.gaiaonline.com/76bd5c99d8f2236e9d3672510e933fdf/http://i278.photobucket.com/albums/kk81/d3m3nt3dpr3p/Tiny-Star-Icon.png');
+  list-style-position: inside;
+  padding: 0;
+}
+
+.results li {
+  font-size: 18px;
+  margin-bottom: 16px;
+}
+
+.star-count {
+  font-weight: bold;
+  margin-right: 16px;
+}
+
+a {
+  color: rgb(96, 181, 204);
+  text-decoration: none;
+}
+
+a:hover {
+  text-decoration: underline;
+}
+
+.search-query {
+  padding: 8px;
+  font-size: 24px;
+  margin-bottom: 18px;
+  margin-top: 36px;
+}
+
+.search-button {
+  padding: 8px 16px;
+  font-size: 24px;
+  color: white;
+  border: 1px solid #ccc;
+  background-color: rgb(96, 181, 204);
+  margin-left: 12px
+}
+
+.search-button:hover {
+  color: rgb(96, 181, 204);
+  background-color: white;
+}
+
+.hide-result {
+  background-color: transparent;
+  border: 0;
+  font-weight: bold;
+  font-size: 18px;
+  margin-left: 18px;
+  cursor: pointer;
+}
+
+.hide-result:hover {
+  color: rgb(96, 181, 204);
+}
+
+button:focus, input:focus {
+  outline: none;
+}
+
+.error {
+  background-color: #FF9632;
+  padding: 20px;
+  box-sizing: border-box;
+  overflow-x: auto;
+  font-family: monospace;
+  font-size: 18px;
+}
+
+a {
+  cursor: pointer;
+}
+
+.repo-description {
+  font-size: 18px;
+}
+
+.profile-photo {
+  width: 32px;
+  margin-right: 10px;
+}
+
+th {
+  text-align: left;
+}
+
+.home-container th {
+  cursor: pointer;
+}
+
+.home-container th:hover {
+  color: rgb(96, 181, 204);
+}
+
+th, td {
+  font-size: 18px;
+  padding-right: 20px;
+}