Reorganize stages into parts

part11/ElmHub.elm

@@ -0,0 +1,129 @@
+module ElmHub (..) where
+
+import Html exposing (..)
+import Html.Attributes exposing (..)
+import Html.Events exposing (..)
+import Html.Lazy exposing (..)
+import Http
+import Task exposing (Task)
+import Effects exposing (Effects)
+import Json.Decode exposing (Decoder, (:=))
+import Json.Encode
+import Signal exposing (Address)
+import Dict exposing (Dict)
+import SearchResult
+
+
+searchFeed : String -> Task x Action
+searchFeed query =
+  let
+    -- See https://developer.github.com/v3/search/#example for how to customize!
+    url =
+      "https://api.github.com/search/repositories?q="
+        ++ query
+        ++ "+language:elm"
+
+    task =
+      Http.get responseDecoder url
+        |> Task.map SetResults
+  in
+    Task.onError task (\_ -> Task.succeed (SetResults []))
+
+
+responseDecoder : Decoder (List SearchResult.Model)
+responseDecoder =
+  "items" := Json.Decode.list SearchResult.decoder
+
+
+type alias Model =
+  { query : String
+  , results : Dict SearchResult.ResultId SearchResult.Model
+  }
+
+
+initialModel : Model
+initialModel =
+  { query = "tutorial"
+  , results = Dict.empty
+  }
+
+
+view : Address Action -> Model -> Html
+view address model =
+  div
+    [ class "content" ]
+    [ header
+        []
+        [ h1 [] [ text "ElmHub" ]
+        , span [ class "tagline" ] [ text "“Like GitHub, but for Elm things.”" ]
+        ]
+    , input [ class "search-query", onInput address SetQuery, defaultValue model.query ] []
+    , button [ class "search-button", onClick address Search ] [ text "Search" ]
+    , ul
+        [ class "results" ]
+        (viewSearchResults address model.results)
+    ]
+
+
+viewSearchResults : Address Action -> Dict SearchResult.ResultId SearchResult.Model -> List Html
+viewSearchResults address results =
+  results
+    |> Dict.values
+    |> List.sortBy (.stars >> negate)
+    |> filterResults
+    |> List.map (lazy3 SearchResult.view address DeleteById)
+
+
+filterResults : List SearchResult.Model -> List SearchResult.Model
+filterResults results =
+  case results of
+    [] ->
+      []
+
+    result :: rest ->
+      if result.stars > 0 then
+        result :: (filterResults rest)
+      else
+        filterResults rest
+
+
+onInput address wrap =
+  on "input" targetValue (\val -> Signal.message address (wrap val))
+
+
+defaultValue str =
+  property "defaultValue" (Json.Encode.string str)
+
+
+type Action
+  = Search
+  | SetQuery String
+  | DeleteById SearchResult.ResultId
+  | SetResults (List SearchResult.Model)
+
+
+update : Action -> Model -> ( Model, Effects Action )
+update action model =
+  case action of
+    Search ->
+      ( model, Effects.task (searchFeed model.query) )
+
+    SetQuery query ->
+      ( { model | query = query }, Effects.none )
+
+    SetResults results ->
+      let
+        resultsById : Dict SearchResult.ResultId SearchResult.Model
+        resultsById =
+          results
+            |> List.map (\result -> ( result.id, result ))
+            |> Dict.fromList
+      in
+        ( { model | results = resultsById }, Effects.none )
+
+    DeleteById id ->
+      let
+        newModel =
+          { model | results = Dict.remove id model.results }
+      in
+        ( newModel, Effects.none )

part11/ElmHub/Css.elm

@@ -0,0 +1,14 @@
+module ElmHub.Css (..) where
+
+import Css exposing (..)
+
+
+css =
+  stylesheet
+    [ ((.) "content")
+        [ width (px 960)
+        , margin2 zero auto
+        , padding (px 30)
+        , fontFamilies [ "Helvetica", "Arial", "serif" ]
+        ]
+    ]

part11/Main.elm

@@ -0,0 +1,27 @@
+module Main (..) where
+
+import StartApp
+import ElmHub exposing (..)
+import Effects exposing (Effects)
+import Task exposing (Task)
+import Html exposing (Html)
+
+
+main : Signal Html
+main =
+  app.html
+
+
+app : StartApp.App Model
+app =
+  StartApp.start
+    { view = view
+    , update = update
+    , init = ( initialModel, Effects.task (searchFeed initialModel.query) )
+    , inputs = []
+    }
+
+
+port tasks : Signal (Task Effects.Never ())
+port tasks =
+  app.tasks

part11/README.md

@@ -0,0 +1,23 @@
+Stage 12
+========
+
+## Installation
+
+```bash
+elm package install
+```
+
+(Answer `y` at the prompt. In rare cases a known issue can cause the download
+to fail; in that case, just run `elm package install` again.)
+
+## Building
+
+```bash
+elm live Main.elm --open -- --output=elm.js
+```
+
+## Compiling CSS
+
+```bash
+elm css Stylesheets.elm
+```

part11/SearchResult.elm

@@ -0,0 +1,44 @@
+module SearchResult (..) where
+
+import Html exposing (..)
+import Html.Attributes exposing (..)
+import Html.Events exposing (..)
+import Json.Decode exposing (Decoder, (:=))
+import Signal exposing (Address)
+import Dict exposing (Dict)
+
+
+type alias ResultId =
+  Int
+
+
+type alias Model =
+  { id : ResultId
+  , name : String
+  , stars : Int
+  }
+
+
+decoder : Decoder Model
+decoder =
+  Json.Decode.object3
+    Model
+    ("id" := Json.Decode.int)
+    ("full_name" := Json.Decode.string)
+    ("stargazers_count" := Json.Decode.int)
+
+
+view : Address a -> (Int -> a) -> Model -> Html
+view address delete result =
+  li
+    []
+    [ span [ class "star-count" ] [ text (toString result.stars) ]
+    , a
+        [ href ("https://github.com/" ++ result.name)
+        , target "_blank"
+        ]
+        [ text result.name ]
+    , button
+        [ class "hide-result", onClick address (delete result.id) ]
+        [ text "X" ]
+    ]

part11/Stylesheets.elm

@@ -0,0 +1,10 @@
+module Stylesheets (..) where
+
+import Css.File exposing (..)
+import ElmHub.Css
+
+
+port files : CssFileStructure
+port files =
+  toFileStructure
+    [ ( "style.css", compile ElmHub.Css.css ) ]

part11/elm-package.json

@@ -0,0 +1,19 @@
+{
+    "version": "1.0.0",
+    "summary": "Like GitHub, but for Elm stuff.",
+    "repository": "https://github.com/rtfeldman/elm-workshop.git",
+    "license": "BSD-3-Clause",
+    "source-directories": [
+        "."
+    ],
+    "exposed-modules": [],
+    "dependencies": {
+        "elm-lang/core": "3.0.0 <= v < 4.0.0",
+        "evancz/elm-effects": "2.0.0 <= v < 3.0.0",
+        "evancz/elm-html": "4.0.0 <= v < 5.0.0",
+        "evancz/elm-http": "3.0.0 <= v < 4.0.0",
+        "evancz/start-app": "2.0.0 <= v < 3.0.0",
+        "rtfeldman/elm-css": "1.0.0 <= v < 2.0.0"
+    },
+    "elm-version": "0.16.0 <= v < 0.17.0"
+}

part11/index.html

@@ -0,0 +1,26 @@
+<!DOCTYPE HTML>
+<html>
+
+<head>
+  <meta charset="UTF-8">
+  <title>ElmHub</title>
+  <script type="text/javascript" src="elm.js"></script>
+
+  <!-- Uncomment the below line to enable elm-reactor support. -->
+  <!-- <script type="text/javascript" src="/_reactor/debug.js"></script> -->
+
+  <link rel="stylesheet" href="style.css">
+  <link rel="icon" type="image/png" href="elm-hub.png">
+</head>
+
+<body>
+</body>
+
+<script type="text/javascript">
+  var app = Elm.fullscreen(Elm.Main, {});
+
+  // Uncomment this line and comment out the above to enable elm-reactor support.
+  // var app = Elm.fullscreenDebug("ElmHub", "Main.elm");
+</script>
+
+</html>

part11/style.css

@@ -0,0 +1,6 @@
+.content {
+    width: 960px;
+    margin: 0 auto;
+    padding: 30px;
+    font-family: Helvetica, Arial, serif;
+}

part11/test/TestRunner.elm

@@ -0,0 +1,15 @@
+module Main where
+
+import Signal exposing (Signal)
+
+import ElmTest exposing (consoleRunner)
+import Console exposing (IO, run)
+import Task
+
+import Tests
+
+console : IO ()
+console = consoleRunner Tests.all
+
+port runner : Signal (Task.Task x ())
+port runner = run console

part11/test/Tests.elm

@@ -0,0 +1,35 @@
+module Tests (..) where
+
+import ElmTest exposing (..)
+import ElmHub exposing (responseDecoder)
+import Json.Decode exposing (decodeString)
+
+
+all : Test
+all =
+  suite
+    "Decoding responses from GitHub"
+    [ test "they can decode empty responses"
+        <| let
+            emptyResponse =
+              """{ "items": [] }"""
+           in
+            assertEqual
+              (decodeString responseDecoder emptyResponse)
+              (Ok [])
+    , test "they can decode responses with results in them"
+        <| let
+            response =
+              """{ "items": [
+                { "id": 5, "full_name": "foo", "stargazers_count": 42 },
+                { "id": 3, "full_name": "bar", "stargazers_count": 77 }
+              ] }"""
+           in
+            assertEqual
+              (decodeString responseDecoder response)
+              (Ok
+                [ { id = 5, name = "foo", stars = 42 }
+                , { id = 3, name = "bar", stars = 77 }
+                ]
+              )
+    ]

part11/test/elm-package.json

@@ -0,0 +1,21 @@
+{
+    "version": "1.0.0",
+    "summary": "Like GitHub, but for Elm stuff.",
+    "repository": "https://github.com/rtfeldman/elm-workshop.git",
+    "license": "BSD-3-Clause",
+    "source-directories": [
+        ".",
+        ".."
+    ],
+    "exposed-modules": [],
+    "dependencies": {
+        "deadfoxygrandpa/elm-test": "3.1.1 <= v < 4.0.0",
+        "elm-lang/core": "3.0.0 <= v < 4.0.0",
+        "evancz/elm-effects": "2.0.0 <= v < 3.0.0",
+        "evancz/elm-html": "4.0.0 <= v < 5.0.0",
+        "evancz/elm-http": "3.0.0 <= v < 4.0.0",
+        "evancz/start-app": "2.0.0 <= v < 3.0.0",
+        "laszlopandy/elm-console": "1.0.3 <= v < 2.0.0"
+    },
+    "elm-version": "0.16.0 <= v < 0.17.0"
+}