Shift everything forward a partg

part9/.gitignore

@@ -0,0 +1 @@
+!Auth.elm

part9/ElmHub.elm

@@ -0,0 +1,137 @@
+module ElmHub exposing (..)
+
+import Html exposing (..)
+import Html.Attributes exposing (class, target, href, property, defaultValue)
+import Html.Events exposing (..)
+import Auth
+import Json.Decode exposing (Decoder)
+import Json.Decode.Pipeline exposing (..)
+
+
+getQueryString : String -> String
+getQueryString query =
+    -- See https://developer.github.com/v3/search/#example for how to customize!
+    "access_token="
+        ++ Auth.token
+        ++ "&q="
+        ++ query
+        ++ "+language:elm&sort=stars&order=desc"
+
+
+responseDecoder : Decoder (List SearchResult)
+responseDecoder =
+    Json.Decode.at [ "items" ] (Json.Decode.list searchResultDecoder)
+
+
+searchResultDecoder : Decoder SearchResult
+searchResultDecoder =
+    decode SearchResult
+        |> required "id" Json.Decode.int
+        |> required "full_name" Json.Decode.string
+        |> required "stargazers_count" Json.Decode.int
+
+
+type alias Model =
+    { query : String
+    , results : List SearchResult
+    , errorMessage : Maybe String
+    }
+
+
+type alias SearchResult =
+    { id : Int
+    , name : String
+    , stars : Int
+    }
+
+
+initialModel : Model
+initialModel =
+    { query = "tutorial"
+    , results = []
+    , errorMessage = Nothing
+    }
+
+
+view : Model -> Html Msg
+view model =
+    div [ class "content" ]
+        [ header []
+            [ h1 [] [ text "ElmHub" ]
+            , span [ class "tagline" ] [ text "Like GitHub, but for Elm things." ]
+            ]
+        , input [ class "search-query", onInput SetQuery, defaultValue model.query ] []
+        , button [ class "search-button", onClick Search ] [ text "Search" ]
+        , viewErrorMessage model.errorMessage
+        , ul [ class "results" ] (List.map viewSearchResult model.results)
+        ]
+
+
+viewErrorMessage : Maybe String -> Html a
+viewErrorMessage errorMessage =
+    case errorMessage of
+        Just message ->
+            div [ class "error" ] [ text message ]
+
+        Nothing ->
+            text ""
+
+
+viewSearchResult : SearchResult -> Html Msg
+viewSearchResult result =
+    li []
+        [ span [ class "star-count" ] [ text (toString result.stars) ]
+        , a [ href ("https://github.com/" ++ result.name), target "_blank" ]
+            [ text result.name ]
+        , button [ class "hide-result", onClick (DeleteById result.id) ]
+            [ text "X" ]
+        ]
+
+
+type Msg
+    = Search
+    | SetQuery String
+    | DeleteById Int
+    | HandleSearchResponse (List SearchResult)
+    | HandleSearchError (Maybe String)
+    | DoNothing
+
+
+update : (String -> Cmd Msg) -> Msg -> Model -> ( Model, Cmd Msg )
+update searchFeed msg model =
+    case msg of
+        Search ->
+            ( model, searchFeed (getQueryString model.query) )
+
+        SetQuery query ->
+            ( { model | query = query }, Cmd.none )
+
+        HandleSearchResponse results ->
+            ( { model | results = results }, Cmd.none )
+
+        HandleSearchError error ->
+            ( { model | errorMessage = error }, Cmd.none )
+
+        DeleteById idToHide ->
+            let
+                newResults =
+                    model.results
+                        |> List.filter (\{ id } -> id /= idToHide)
+
+                newModel =
+                    { model | results = newResults }
+            in
+                ( newModel, Cmd.none )
+
+        DoNothing ->
+            ( model, Cmd.none )
+
+
+decodeGithubResponse : Json.Decode.Value -> Msg
+decodeGithubResponse value =
+    case Json.Decode.decodeValue responseDecoder value of
+        Ok results ->
+            HandleSearchResponse results
+
+        Err err ->
+            HandleSearchError (Just err)

part9/Main.elm

@@ -0,0 +1,31 @@
+port module Main exposing (..)
+
+import ElmHub exposing (..)
+import Html.App as Html
+import Json.Decode
+
+
+main : Program Never
+main =
+    Html.program
+        { view = view
+        , update = update githubSearch
+        , init = ( initialModel, githubSearch (getQueryString initialModel.query) )
+        , subscriptions = \_ -> githubResponse decodeResponse
+        }
+
+
+decodeResponse : Json.Decode.Value -> Msg
+decodeResponse json =
+    case Json.Decode.decodeValue responseDecoder json of
+        Err err ->
+            HandleSearchError (Just err)
+
+        Ok results ->
+            HandleSearchResponse results
+
+
+port githubSearch : String -> Cmd msg
+
+
+port githubResponse : (Json.Decode.Value -> msg) -> Sub msg

part9/README.md

@@ -0,0 +1,45 @@
+Part 8
+======
+
+The instructor will paste notes from the lesson, including code examples from
+Q&A, in [this document](https://docs.google.com/document/d/1ApuSOk9DP0YsQrxhW7-WE8UOEAV4PPnLDDeqUOL2o5k/edit?usp=sharing).
+
+## Installation
+
+```bash
+elm-package install
+```
+
+(Answer `y` when prompted.)
+
+
+## Building
+
+```bash
+elm-live Main.elm --open --output=elm.js
+```
+
+## Running Tests
+
+Do either (or both!) of the following:
+
+#### Running tests on the command line
+
+```bash
+elm-test
+```
+
+#### Running tests in a browser
+
+```bash
+cd tests
+elm-reactor
+```
+
+Then visit [localhost:8000](http://localhost:8000) and choose `HtmlRunner.elm`.
+
+## References
+
+* [Using Elm packages](https://github.com/elm-lang/elm-package/blob/master/README.md#basic-usage)
+* [elm-test documentation](http://package.elm-lang.org/packages/project-fuzzball/test/latest)
+* [`(<|)` documentation](http://package.elm-lang.org/packages/elm-lang/core/4.0.0/Basics#<|)

part9/elm-package.json

@@ -0,0 +1,18 @@
+{
+    "version": "1.0.0",
+    "summary": "Like GitHub, but for Elm stuff.",
+    "repository": "https://github.com/rtfeldman/elm-workshop.git",
+    "license": "BSD-3-Clause",
+    "source-directories": [
+        ".",
+        ".."
+    ],
+    "exposed-modules": [],
+    "dependencies": {
+        "NoRedInk/elm-decode-pipeline": "1.1.2 <= v < 2.0.0",
+        "elm-lang/core": "4.0.1 <= v < 5.0.0",
+        "elm-lang/html": "1.0.0 <= v < 2.0.0",
+        "evancz/elm-http": "3.0.1 <= v < 4.0.0"
+    },
+    "elm-version": "0.17.0 <= v < 0.18.0"
+}

part9/index.html

@@ -0,0 +1,36 @@
+<!DOCTYPE HTML>
+<html>
+
+<head>
+  <meta charset="UTF-8">
+  <title>ElmHub</title>
+  <script type="text/javascript" src="github.js"></script>
+  <script type="text/javascript" src="elm.js"></script>
+  <link rel="stylesheet" href="style.css">
+  <link rel="icon" type="image/png" href="elm-hub.png">
+</head>
+
+<body>
+  <div id="elm-landing-pad"></div>
+</body>
+
+<script type="text/javascript">
+  // documentation: https://github.com/michael/github
+  var github = new Github();
+
+  var app = Elm.Main.embed(document.getElementById("elm-landing-pad"));
+
+  function searchGithub(query) {
+    console.log("Searching for", query);
+
+    github.getSearch(query).repositories({}, function (err, repositories) {
+      console.log("Got response", repositories);
+
+      app.ports.githubResponse.send(repositories);
+    });
+  }
+
+  app.ports.githubSearch.subscribe(searchGithub);
+</script>
+
+</html>

part9/style.css

@@ -0,0 +1,101 @@
+
+.content {
+  width: 960px;
+  margin: 0 auto;
+  padding: 30px;
+  font-family: Helvetica, Arial, serif;
+}
+
+header {
+  position: relative;
+  padding: 6px 12px;
+  height: 36px;
+  background-color: rgb(96, 181, 204);
+}
+
+h1 {
+  color: white;
+  font-weight: normal;
+  margin: 0;
+}
+
+.tagline {
+  color: #eee;
+  position: absolute;
+  right: 16px;
+  top: 12px;
+  font-size: 24px;
+  font-style: italic;
+}
+
+.results {
+  list-style-image: url('http://img-cache.cdn.gaiaonline.com/76bd5c99d8f2236e9d3672510e933fdf/http://i278.photobucket.com/albums/kk81/d3m3nt3dpr3p/Tiny-Star-Icon.png');
+  list-style-position: inside;
+  padding: 0;
+}
+
+.results li {
+  font-size: 18px;
+  margin-bottom: 16px;
+}
+
+.star-count {
+  font-weight: bold;
+  margin-right: 16px;
+}
+
+a {
+  color: rgb(96, 181, 204);
+  text-decoration: none;
+}
+
+a:hover {
+  text-decoration: underline;
+}
+
+.search-query {
+  padding: 8px;
+  font-size: 24px;
+  margin-bottom: 18px;
+  margin-top: 36px;
+}
+
+.search-button {
+  padding: 8px 16px;
+  font-size: 24px;
+  color: white;
+  border: 1px solid #ccc;
+  background-color: rgb(96, 181, 204);
+  margin-left: 12px
+}
+
+.search-button:hover {
+  color: rgb(96, 181, 204);
+  background-color: white;
+}
+
+.hide-result {
+  background-color: transparent;
+  border: 0;
+  font-weight: bold;
+  font-size: 18px;
+  margin-left: 18px;
+  cursor: pointer;
+}
+
+.hide-result:hover {
+  color: rgb(96, 181, 204);
+}
+
+button:focus, input:focus {
+  outline: none;
+}
+
+.error {
+  background-color: #FF9632;
+  padding: 20px;
+  box-sizing: border-box;
+  overflow-x: auto;
+  font-family: monospace;
+  font-size: 18px;
+}

part9/tests/Auth.elm

@@ -0,0 +1,7 @@
+module Auth exposing (token)
+
+
+token : String
+token =
+    -- Tests don't need a real token.
+    ""

part9/tests/HtmlRunner.elm

@@ -0,0 +1,16 @@
+module HtmlRunner exposing (..)
+
+import Tests
+import Test.Runner.Html as Runner
+
+
+-- To run this:
+--
+-- cd into part8/test
+-- elm-reactor
+-- navigate to HtmlRunner.elm
+
+
+main : Program Never
+main =
+    Runner.run Tests.all

part9/tests/Main.elm

@@ -0,0 +1,18 @@
+port module Main exposing (..)
+
+import Tests
+import Test.Runner.Node as Runner
+import Json.Decode exposing (Value)
+
+
+-- To run this:
+--
+-- elm-test
+
+
+main : Program Value
+main =
+    Runner.run emit Tests.all
+
+
+port emit : ( String, Value ) -> Cmd msg

part9/tests/Tests.elm

@@ -0,0 +1,70 @@
+module Tests exposing (..)
+
+import Test exposing (..)
+import Fuzz exposing (..)
+import Expect exposing (Expectation)
+import ElmHub exposing (responseDecoder)
+import Json.Decode exposing (decodeString, Value)
+import String
+
+
+all : Test
+all =
+    describe "GitHub Response Decoder"
+        [ test "it results in an Err for invalid JSON" <|
+            \() ->
+                let
+                    json =
+                        """{ "pizza": [] }"""
+
+                    isErrorResult result =
+                        -- TODO return True if the given Result is an Err of some sort,
+                        -- and False if it is an Ok of some sort.
+                        --
+                        -- Result docs: http://package.elm-lang.org/packages/elm-lang/core/4.0.1/Result
+                        False
+                in
+                    json
+                        |> decodeString responseDecoder
+                        |> isErrorResult
+                        |> Expect.true "Expected decoding an invalid response to return an Err."
+        , test "it successfully decodes a valid response" <|
+            \() ->
+                """{ "items": [
+                    /* TODO: put JSON here! */
+                 ] }"""
+                    |> decodeString responseDecoder
+                    |> Expect.equal
+                        (Ok
+                            [ { id = 5, name = "foo", stars = 42 }
+                            , { id = 3, name = "bar", stars = 77 }
+                            ]
+                        )
+        , test "it decodes one SearchResult for each 'item' in the JSON" <|
+            \() ->
+                let
+                    -- TODO convert this to a fuzz test that generates a random
+                    -- list of ids instead of this hardcoded list of three ids.
+                    --
+                    -- fuzz test docs: http://package.elm-lang.org/packages/project-fuzzball/test/2.0.1/Test#fuzz
+                    -- Fuzzer docs: http://package.elm-lang.org/packages/project-fuzzball/test/2.0.1/Fuzz
+                    ids =
+                        [ 12, 5, 76 ]
+
+                    jsonFromId id =
+                        """{"id": """ ++ toString id ++ """, "full_name": "foo", "stargazers_count": 42}"""
+
+                    jsonItems =
+                        String.join ", " (List.map jsonFromId ids)
+
+                    json =
+                        """{ "items": [""" ++ jsonItems ++ """] }"""
+                in
+                    case decodeString responseDecoder json of
+                        Ok results ->
+                            List.length results
+                                |> Expect.equal (List.length ids)
+
+                        Err err ->
+                            Expect.fail ("JSON decoding failed unexpectedly: " ++ err)
+        ]

part9/tests/elm-package.json

@@ -0,0 +1,21 @@
+{
+    "version": "1.0.0",
+    "summary": "Like GitHub, but for Elm stuff.",
+    "repository": "https://github.com/rtfeldman/elm-workshop.git",
+    "license": "BSD-3-Clause",
+    "source-directories": [
+        ".",
+        ".."
+    ],
+    "exposed-modules": [],
+    "dependencies": {
+        "NoRedInk/elm-decode-pipeline": "1.1.2 <= v < 2.0.0",
+        "elm-community/elm-test": "2.0.1 <= v < 3.0.0",
+        "elm-lang/core": "4.0.1 <= v < 5.0.0",
+        "elm-lang/html": "1.0.0 <= v < 2.0.0",
+        "evancz/elm-http": "3.0.1 <= v < 4.0.0",
+        "rtfeldman/html-test-runner": "1.0.0 <= v < 2.0.0",
+        "rtfeldman/node-test-runner": "2.0.0 <= v < 3.0.0"
+    },
+    "elm-version": "0.17.0 <= v < 0.18.0"
+}