Shift everything forward a partg

part12/part11/ElmHub.elm

@@ -0,0 +1,146 @@
+module ElmHub exposing (..)
+
+import Html exposing (..)
+import Html.Attributes exposing (..)
+import Html.Events exposing (..)
+import Html.App as Html
+import Http
+import Auth
+import Task exposing (Task)
+import Json.Decode exposing (Decoder)
+import Dict exposing (Dict)
+import SearchResult
+
+
+searchFeed : String -> Cmd Msg
+searchFeed query =
+    let
+        url =
+            "https://api.github.com/search/repositories?access_token="
+                ++ Auth.token
+                ++ "&q="
+                ++ query
+                ++ "+language:elm&sort=stars&order=desc"
+    in
+        Task.perform HandleSearchError HandleSearchResponse (Http.get responseDecoder url)
+
+
+responseDecoder : Decoder (List SearchResult.Model)
+responseDecoder =
+    Json.Decode.at [ "items" ] (Json.Decode.list SearchResult.decoder)
+
+
+type alias Model =
+    { query : String
+    , results : Dict Int SearchResult.Model
+    , errorMessage : Maybe String
+    }
+
+
+initialModel : Model
+initialModel =
+    { query = "tutorial"
+    , results = Dict.empty
+    , errorMessage = Nothing
+    }
+
+
+view : Model -> Html Msg
+view model =
+    div [ class "content" ]
+        [ header []
+            [ h1 [] [ text "ElmHub" ]
+            , span [ class "tagline" ] [ text "Like GitHub, but for Elm things." ]
+            ]
+        , input [ class "search-query", onInput SetQuery, defaultValue model.query ] []
+        , button [ class "search-button", onClick Search ] [ text "Search" ]
+        , viewErrorMessage model.errorMessage
+        , ul [ class "results" ] (viewSearchResults model.results)
+        ]
+
+
+viewErrorMessage : Maybe String -> Html a
+viewErrorMessage errorMessage =
+    case errorMessage of
+        Just message ->
+            div [ class "error" ] [ text message ]
+
+        Nothing ->
+            text ""
+
+
+viewSearchResults : Dict Int SearchResult.Model -> List (Html Msg)
+viewSearchResults results =
+    results
+        |> Dict.values
+        |> List.sortBy (.stars >> negate)
+        |> filterResults
+        |> List.map viewSearchResult
+
+
+filterResults : List SearchResult.Model -> List SearchResult.Model
+filterResults results =
+    -- TODO filter out repos with 0 stars
+    -- using a case-expression rather than List.filter
+    results
+
+
+viewSearchResult : SearchResult.Model -> Html Msg
+viewSearchResult result =
+    result
+        |> SearchResult.view
+        |> Html.App.map (UpdateSearchResult result.id)
+
+
+type Msg
+    = Search
+    | SetQuery String
+    | UpdateSearchResult Int SearchResult.Msg
+    | HandleSearchResponse (List SearchResult.Model)
+    | HandleSearchError Http.Error
+
+
+update : Msg -> Model -> ( Model, Cmd Msg )
+update msg model =
+    case msg of
+        Search ->
+            model ! [ searchFeed model.query ]
+
+        SetQuery query ->
+            { model | query = query, errorMessage = Nothing } ! []
+
+        HandleSearchError error ->
+            case error of
+                Http.UnexpectedPayload str ->
+                    { model | errorMessage = Just str } ! []
+
+                _ ->
+                    { model | errorMessage = Just "Error loading search results" } ! []
+
+        HandleSearchResponse results ->
+            let
+                resultsById : Dict Int SearchResult.Model
+                resultsById =
+                    results
+                        |> List.map (\result -> ( result.id, result ))
+                        |> Dict.fromList
+            in
+                { model | results = resultsById } ! []
+
+        UpdateSearchResult id childMsg ->
+            case Dict.get id model.results of
+                Nothing ->
+                    model ! []
+
+                Just childModel ->
+                    let
+                        ( newChildModel, childCmd ) =
+                            SearchResult.update childMsg childModel
+
+                        cmd =
+                            Cmd.map (UpdateSearchResult id) childCmd
+
+                        newResults =
+                            Dict.insert id newChildModel model.results
+                    in
+                        { model | results = newResults } ! [ cmd ]

part12/part11/Main.elm

@@ -0,0 +1,14 @@
+module Main exposing (..)
+
+import ElmHub exposing (..)
+import Html.App as Html
+
+
+main : Program Never
+main =
+    Html.program
+        { view = view
+        , update = update
+        , init = ( initialModel, searchFeed initialModel.query )
+        , subscriptions = \_ -> Sub.none
+        }

part12/part11/README.md

@@ -0,0 +1,20 @@
+Part 11
+=======
+
+The instructor will paste notes from the lesson, including code examples from
+Q&A, in [this document](https://docs.google.com/document/d/1ApuSOk9DP0YsQrxhW7-WE8UOEAV4PPnLDDeqUOL2o5k/edit?usp=sharing).
+
+## Installation
+
+```bash
+elm-package install
+```
+
+(Answer `y` when prompted.)
+
+
+## Building
+
+```bash
+elm-live Main.elm --open --output=elm.js
+```

part12/part11/SearchResult.elm

@@ -0,0 +1,63 @@
+module SearchResult exposing (..)
+
+import Html exposing (..)
+import Html.Attributes exposing (class, target, href, property, defaultValue)
+import Html.Events exposing (..)
+import Json.Decode exposing (Decoder)
+import Json.Decode.Pipeline exposing (..)
+
+
+type alias Model =
+    { id : Int
+    , name : String
+    , stars : Int
+    , expanded : Bool
+    }
+
+
+type Msg
+    = Expand
+    | Collapse
+
+
+decoder : Decoder Model
+decoder =
+    decode Model
+        |> required "id" Json.Decode.int
+        |> required "full_name" Json.Decode.string
+        |> required "stargazers_count" Json.Decode.int
+        |> hardcoded True
+
+
+update : Msg -> Model -> ( Model, Cmd Msg )
+update msg model =
+    case msg of
+        Expand ->
+            { model | expanded = True } ! []
+
+        Collapse ->
+            { model | expanded = False } ! []
+
+
+view : Model -> Html Msg
+view model =
+    li [] <|
+        if model.expanded then
+            [ span [ class "star-count" ] [ text (toString model.stars) ]
+            , a
+                [ href
+                    ("https://github.com/"
+                        ++ (Debug.log "TODO we should not see this when typing in the search box!"
+                                model.name
+                           )
+                    )
+                , target "_blank"
+                ]
+                [ text model.name ]
+            , button [ class "hide-result", onClick Collapse ]
+                [ text "X" ]
+            ]
+        else
+            [ button [ class "expand-result", onClick Expand ]
+                [ text "Show" ]
+            ]

part12/part11/elm-package.json

@@ -0,0 +1,18 @@
+{
+    "version": "1.0.0",
+    "summary": "Like GitHub, but for Elm stuff.",
+    "repository": "https://github.com/rtfeldman/elm-workshop.git",
+    "license": "BSD-3-Clause",
+    "source-directories": [
+        ".",
+        ".."
+    ],
+    "exposed-modules": [],
+    "dependencies": {
+        "NoRedInk/elm-decode-pipeline": "1.1.2 <= v < 2.0.0",
+        "elm-lang/core": "4.0.1 <= v < 5.0.0",
+        "elm-lang/html": "1.0.0 <= v < 2.0.0",
+        "evancz/elm-http": "3.0.1 <= v < 4.0.0"
+    },
+    "elm-version": "0.17.0 <= v < 0.18.0"
+}

part12/part11/index.html

@@ -0,0 +1,20 @@
+<!DOCTYPE HTML>
+<html>
+
+<head>
+  <meta charset="UTF-8">
+  <title>ElmHub</title>
+  <script type="text/javascript" src="elm.js"></script>
+
+  <link rel="stylesheet" href="style.css">
+  <link rel="icon" type="image/png" href="elm-hub.png">
+</head>
+
+<body>
+</body>
+
+<script type="text/javascript">
+  var app = Elm.Main.fullscreen();
+</script>
+
+</html>

part12/part11/style.css

@@ -0,0 +1,101 @@
+
+.content {
+  width: 960px;
+  margin: 0 auto;
+  padding: 30px;
+  font-family: Helvetica, Arial, serif;
+}
+
+header {
+  position: relative;
+  padding: 6px 12px;
+  height: 36px;
+  background-color: rgb(96, 181, 204);
+}
+
+h1 {
+  color: white;
+  font-weight: normal;
+  margin: 0;
+}
+
+.tagline {
+  color: #eee;
+  position: absolute;
+  right: 16px;
+  top: 12px;
+  font-size: 24px;
+  font-style: italic;
+}
+
+.results {
+  list-style-image: url('http://img-cache.cdn.gaiaonline.com/76bd5c99d8f2236e9d3672510e933fdf/http://i278.photobucket.com/albums/kk81/d3m3nt3dpr3p/Tiny-Star-Icon.png');
+  list-style-position: inside;
+  padding: 0;
+}
+
+.results li {
+  font-size: 18px;
+  margin-bottom: 16px;
+}
+
+.star-count {
+  font-weight: bold;
+  margin-right: 16px;
+}
+
+a {
+  color: rgb(96, 181, 204);
+  text-decoration: none;
+}
+
+a:hover {
+  text-decoration: underline;
+}
+
+.search-query {
+  padding: 8px;
+  font-size: 24px;
+  margin-bottom: 18px;
+  margin-top: 36px;
+}
+
+.search-button {
+  padding: 8px 16px;
+  font-size: 24px;
+  color: white;
+  border: 1px solid #ccc;
+  background-color: rgb(96, 181, 204);
+  margin-left: 12px
+}
+
+.search-button:hover {
+  color: rgb(96, 181, 204);
+  background-color: white;
+}
+
+.hide-result {
+  background-color: transparent;
+  border: 0;
+  font-weight: bold;
+  font-size: 18px;
+  margin-left: 18px;
+  cursor: pointer;
+}
+
+.hide-result:hover {
+  color: rgb(96, 181, 204);
+}
+
+button:focus, input:focus {
+  outline: none;
+}
+
+.error {
+  background-color: #FF9632;
+  padding: 20px;
+  box-sizing: border-box;
+  overflow-x: auto;
+  font-family: monospace;
+  font-size: 18px;
+}